regrid_consts.F90

Go to the documentation of this file.

!> Contains constants for interpreting input parameters that control regridding.
module regrid_consts
 
! This file is part of MOM6. See LICENSE.md for the license.
 
use mom_error_handler, only : mom_error, fatal
use mom_string_functions, only : uppercase
 
implicit none ; public
 
! List of regridding types. These should be consecutive and starting at 1.
! This allows them to be used as array indices.
integer, parameter :: regridding_layer     = 1      !< Layer mode identifier
integer, parameter :: regridding_zstar     = 2      !< z* coordinates identifier
integer, parameter :: regridding_rho       = 3      !< Density coordinates identifier
integer, parameter :: regridding_sigma     = 4      !< Sigma coordinates identifier
integer, parameter :: regridding_arbitrary = 5      !< Arbitrary coordinates identifier
integer, parameter :: regridding_hycom1    = 6      !< Simple HyCOM coordinates without BBL
integer, parameter :: regridding_slight    = 7      !< Identifier for stretched coordinates in the
                                                    !! lightest water, isopycnal below
integer, parameter :: regridding_sigma_shelf_zstar = 8 !< Identifiered for z* coordinates at the bottom,
                                                    !!  sigma-near the top
integer, parameter :: regridding_adaptive = 9       !< Adaptive coordinate mode identifier
 
character(len=*), parameter :: regridding_layer_string = "LAYER"   !< Layer string
character(len=*), parameter :: regridding_zstar_string_old = "Z*"  !< z* string (legacy name)
character(len=*), parameter :: regridding_zstar_string = "ZSTAR"   !< z* string
character(len=*), parameter :: regridding_rho_string   = "RHO"     !< Rho string
character(len=*), parameter :: regridding_sigma_string = "SIGMA"   !< Sigma string
character(len=*), parameter :: regridding_arbitrary_string = "ARB" !< Arbitrary coordinates
character(len=*), parameter :: regridding_hycom1_string = "HYCOM1" !< Hycom string
character(len=*), parameter :: regridding_slight_string = "SLIGHT" !< Hybrid S-rho string
character(len=*), parameter :: regridding_sigma_shelf_zstar_string = "SIGMA_SHELF_ZSTAR" !< Hybrid z*/sigma
character(len=*), parameter :: regridding_adaptive_string = "ADAPTIVE" !< Adaptive coordinate string
character(len=*), parameter :: default_coordinate_mode = regridding_layer_string !< Default coordinate mode
 
!> Returns a string with the coordinate units associated with the coordinate mode.
interface coordinateunits
  module procedure coordinateunitsi
  module procedure coordinateunitss
end interface
 
!> Returns true if the coordinate is dependent on the state density, returns false otherwise.
interface state_dependent
  module procedure state_dependent_char
  module procedure state_dependent_int
end interface
 
contains
 
!> Parse a string parameter specifying the coordinate mode and
!! return the appropriate enumerated integer
function coordinatemode(string)
  integer :: coordinatemode !< Enumerated integer indicating coordinate mode
  character(len=*), intent(in) :: string !< String to indicate coordinate mode
  select case ( uppercase(trim(string)) )
    case (trim(regridding_layer_string)); coordinatemode = regridding_layer
    case (trim(regridding_zstar_string)); coordinatemode = regridding_zstar
    case (trim(regridding_zstar_string_old)); coordinatemode = regridding_zstar
    case (trim(regridding_rho_string));   coordinatemode = regridding_rho
    case (trim(regridding_sigma_string)); coordinatemode = regridding_sigma
    case (trim(regridding_hycom1_string)); coordinatemode = regridding_hycom1
    case (trim(regridding_slight_string)); coordinatemode = regridding_slight
    case (trim(regridding_arbitrary_string)); coordinatemode = regridding_arbitrary
    case (trim(regridding_sigma_shelf_zstar_string)); coordinatemode = regridding_sigma_shelf_zstar
    case (trim(regridding_adaptive_string)); coordinatemode = regridding_adaptive
    case default ; call mom_error(fatal, "coordinateMode: "//&
       "Unrecognized choice of coordinate ("//trim(string)//").")
  end select
end function coordinatemode
 
!> Returns a string with the coordinate units associated with the
!! enumerated integer,
function coordinateunitsi(coordMode)
  character(len=16) :: coordinateunitsi !< Units of coordinate
  integer, intent(in) :: coordmode !< Coordinate mode
  select case ( coordmode )
    case (regridding_layer); coordinateunitsi = "kg m^-3"
    case (regridding_zstar); coordinateunitsi = "m"
    case (regridding_sigma_shelf_zstar); coordinateunitsi = "m"
    case (regridding_rho);   coordinateunitsi = "kg m^-3"
    case (regridding_sigma); coordinateunitsi = "Non-dimensional"
    case (regridding_hycom1); coordinateunitsi = "m"
    case (regridding_slight); coordinateunitsi = "m"
    case (regridding_adaptive); coordinateunitsi = "m"
    case default ; call mom_error(fatal, "coordinateUnts: "//&
       "Unrecognized coordinate mode.")
  end select
end function coordinateunitsi
 
!> Returns a string with the coordinate units associated with the
!! string defining the coordinate mode.
function coordinateunitss(string)
  character(len=16) :: coordinateunitss !< Units of coordinate
  character(len=*), intent(in) :: string !< Coordinate mode
  integer :: coordmode
  coordmode = coordinatemode(string)
  coordinateunitss = coordinateunitsi(coordmode)
end function coordinateunitss
 
!> Returns true if the coordinate is dependent on the state density, returns false otherwise.
logical function state_dependent_char(string)
  character(len=*), intent(in) :: string !< String to indicate coordinate mode
 
  state_dependent_char = state_dependent_int( coordinatemode(string) )
 
end function state_dependent_char
 
!> Returns true if the coordinate is dependent on the state density, returns false otherwise.
logical function state_dependent_int(mode)
  integer, intent(in) :: mode !< Coordinate mode
  select case ( mode )
    case (regridding_layer); state_dependent_int = .true.
    case (regridding_zstar); state_dependent_int = .false.
    case (regridding_sigma_shelf_zstar); state_dependent_int = .false.
    case (regridding_rho);   state_dependent_int = .true.
    case (regridding_sigma); state_dependent_int = .false.
    case (regridding_hycom1); state_dependent_int = .true.
    case (regridding_slight); state_dependent_int = .true.
    case (regridding_adaptive); state_dependent_int = .true.
    case default ; call mom_error(fatal, "state_dependent: "//&
       "Unrecognized choice of coordinate.")
  end select
end function state_dependent_int
 
end module regrid_consts