time_utils.F90

Go to the documentation of this file.

!> Set of time utilities for converting between FMS and ESMF time type.
module time_utils_mod
 
! FMS
use fms_mod,            only: uppercase
use mpp_mod,            only: mpp_error, fatal
use time_manager_mod,   only: time_type, set_time, set_date, get_date
use time_manager_mod,   only: gregorian, julian, noleap, thirty_day_months, no_calendar
use time_manager_mod,   only: fms_get_calendar_type => get_calendar_type
! ESMF
use esmf,               only: esmf_calkind_flag, esmf_calkind_gregorian
use esmf,               only: esmf_calkind_julian, esmf_calkind_noleap
use esmf,               only: esmf_calkind_360day, esmf_calkind_nocalendar
use esmf,               only: esmf_time, esmf_timeget, esmf_logfounderror
use esmf,               only: esmf_logerr_passthru,esmf_timeinterval
use esmf,               only: esmf_timeintervalget, esmf_timeset, esmf_success
 
implicit none; private
 
!> Converts calendar from FMS to ESMF format
interface fms2esmf_cal
  module procedure fms2esmf_cal_c
  module procedure fms2esmf_cal_i
end interface fms2esmf_cal
 
!> Converts time from FMS to ESMF format
interface esmf2fms_time
  module procedure esmf2fms_time_t
  module procedure esmf2fms_timestep
end interface esmf2fms_time
 
public fms2esmf_cal
public esmf2fms_time
public fms2esmf_time
public string_to_date
 
contains
 
!> Sets fms2esmf_cal_c to the corresponding ESMF calendar type
function fms2esmf_cal_c(calendar)
  type(esmf_calkind_flag)            :: fms2esmf_cal_c !< ESMF calendar type
  character(len=*), intent(in)       :: calendar       !< Type of calendar
 
  select case( uppercase(trim(calendar)) )
  case( 'GREGORIAN' )
    fms2esmf_cal_c = esmf_calkind_gregorian
  case( 'JULIAN' )
    fms2esmf_cal_c = esmf_calkind_julian
  case( 'NOLEAP' )
    fms2esmf_cal_c = esmf_calkind_noleap
  case( 'THIRTY_DAY' )
    fms2esmf_cal_c = esmf_calkind_360day
  case( 'NO_CALENDAR' )
    fms2esmf_cal_c = esmf_calkind_nocalendar
  case default
    call mpp_error(fatal, &
    'ocean_solo: ocean_solo_nml entry calendar must be one of GREGORIAN|JULIAN|NOLEAP|THIRTY_DAY|NO_CALENDAR.' )
  end select
end function fms2esmf_cal_c
 
!> Sets fms2esmf_cal_i to the corresponding ESMF calendar type
function fms2esmf_cal_i(calendar)
  type(esmf_calkind_flag)            :: fms2esmf_cal_i !< ESMF calendar structure
  integer, intent(in)                :: calendar       !< Type of calendar
 
  select case(calendar)
    case(thirty_day_months)
      fms2esmf_cal_i = esmf_calkind_360day
    case(gregorian)
      fms2esmf_cal_i = esmf_calkind_gregorian
    case(julian)
      fms2esmf_cal_i = esmf_calkind_julian
    case(noleap)
      fms2esmf_cal_i = esmf_calkind_noleap
    case(no_calendar)
      fms2esmf_cal_i = esmf_calkind_nocalendar
  end select
end function fms2esmf_cal_i
 
!> Converts date from ESMF format to FMS format.
function esmf2fms_time_t(time)
  type(time_type)                    :: esmf2fms_time_t !< FMS time structure
  type(esmf_time), intent(in)        :: time            !< ESMF time structure
 
  ! Local Variables
  integer                            :: yy, mm, dd, h, m, s
  type(esmf_calkind_flag)            :: calkind
 
  integer                            :: rc
 
  call esmf_timeget(time, yy=yy, mm=mm, dd=dd, h=h, m=m, s=s, &
      calkindflag=calkind, rc=rc)
  if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
    line=__line__, &
    file=__file__)) &
    return  ! bail out
 
  esmf2fms_time_t = set_date(yy, mm, dd, h, m, s)
 
end function esmf2fms_time_t
 
!> Converts time-interval from ESMF format to FMS format.
function esmf2fms_timestep(timestep)
  type(time_type)                    :: esmf2fms_timestep !< FMS time structure
  type(esmf_timeinterval), intent(in):: timestep          !< time-interval following
                                                          !! ESMF format [s]
  ! Local Variables
  integer                            :: s
  type(esmf_calkind_flag)            :: calkind
 
  integer                            :: rc
 
  call esmf_timeintervalget(timestep, s=s, calkindflag=calkind, rc=rc)
  if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
    line=__line__, &
    file=__file__)) &
    return  ! bail out
 
  esmf2fms_timestep = set_time(s, 0)
 
end function esmf2fms_timestep
 
!> Converts date from FMS format to ESMF format.
function fms2esmf_time(time, calkind)
  type(esmf_time)                    :: fms2esmf_time !< ESMF time structure
  type(time_type), intent(in)        :: time          !< FMS time structure
  type(esmf_calkind_flag), intent(in), optional :: calkind !< ESMF calendar structure
 
  ! Local Variables
  integer                            :: yy, mm, d, h, m, s
  type(esmf_calkind_flag)            :: l_calkind
 
  integer                            :: rc
 
  if(present(calkind)) then
    l_calkind = calkind
  else
    l_calkind = fms2esmf_cal(fms_get_calendar_type())
  endif
 
  call get_date(time, yy, mm, d, h, m, s)
 
  call esmf_timeset(fms2esmf_time, yy=yy, mm=mm, d=d, h=h, m=m, s=s, &
      calkindflag=l_calkind, rc=rc)
  if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
    line=__line__, &
    file=__file__)) &
    return  ! bail out
 
end function fms2esmf_time
 
!> Converts a string (I4.4,I2.2,I2.2,".",I2.2,I2.2,I2.2) that represents
!! yr, mon, day, hr, min, sec to a FMS data format.
function string_to_date(string, rc)
  character(len=15), intent(in)           :: string        !< String representing a date
  integer, intent(out), optional          :: rc            !< ESMF error handler
  type(time_type)                         :: string_to_date!< FMS time structure
 
  ! Local variables
  integer                                 :: yr,mon,day,hr,min,sec
 
  if(present(rc)) rc = esmf_success
 
  read(string, '(I4.4,I2.2,I2.2,".",I2.2,I2.2,I2.2)') yr, mon, day, hr, min, sec
  string_to_date = set_date(yr, mon, day, hr, min, sec)
 
end function string_to_date
 
end module time_utils_mod