module_mp_tempo_utils_v2.F90

! Utilities for TEMPO Microphysics
!=================================================================================================================
module module_mp_tempo_utils_v2
 
    use machine, only: wp => kind_phys, sp => kind_sngl_prec, dp => kind_dbl_prec
    use module_mp_tempo_params, only: pi, rho_i, am_r
 
    implicit none
 
    public 
contains
    !=================================================================================================================
 
    elemental real function make_icenumber (Q_ice, temp)
 
        !IMPLICIT NONE
        real, intent(in):: q_ice, temp
        integer idx_rei
        real corr, reice, deice
        double precision lambda
 
        !+---+-----------------------------------------------------------------+
        !..Table of lookup values of radiative effective radius of ice crystals
        !.. as a function of Temperature from -94C to 0C.  Taken from WRF RRTMG
        !.. radiation code where it is attributed to Jon Egill Kristjansson
        !.. and coauthors.
        !+---+-----------------------------------------------------------------+
 
        real, dimension(95), parameter:: retab = (/                       &
            5.92779, 6.26422, 6.61973, 6.99539, 7.39234,                   &
            7.81177, 8.25496, 8.72323, 9.21800, 9.74075, 10.2930,          &
            10.8765, 11.4929, 12.1440, 12.8317, 13.5581, 14.2319,          &
            15.0351, 15.8799, 16.7674, 17.6986, 18.6744, 19.6955,          &
            20.7623, 21.8757, 23.0364, 24.2452, 25.5034, 26.8125,          &
            27.7895, 28.6450, 29.4167, 30.1088, 30.7306, 31.2943,          &
            31.8151, 32.3077, 32.7870, 33.2657, 33.7540, 34.2601,          &
            34.7892, 35.3442, 35.9255, 36.5316, 37.1602, 37.8078,          &
            38.4720, 39.1508, 39.8442, 40.5552, 41.2912, 42.0635,          &
            42.8876, 43.7863, 44.7853, 45.9170, 47.2165, 48.7221,          &
            50.4710, 52.4980, 54.8315, 57.4898, 60.4785, 63.7898,          &
            65.5604, 71.2885, 75.4113, 79.7368, 84.2351, 88.8833,          &
            93.6658, 98.5739, 103.603, 108.752, 114.025, 119.424,          &
            124.954, 130.630, 136.457, 142.446, 148.608, 154.956,          &
            161.503, 168.262, 175.248, 182.473, 189.952, 197.699,          &
            205.728, 214.055, 222.694, 231.661, 240.971, 250.639 /)
 
        if (q_ice == 0) then
            make_icenumber = 0
            return
        end if
 
        !+---+-----------------------------------------------------------------+
        !..From the model 3D temperature field, subtract 179K for which
        !.. index value of retab as a start.  Value of corr is for
        !.. interpolating between neighboring values in the table.
        !+---+-----------------------------------------------------------------+
 
        idx_rei = int(temp-179.)
        idx_rei = min(max(idx_rei,1),94)
        corr = temp - int(temp)
        reice = retab(idx_rei)*(1.-corr) + retab(idx_rei+1)*corr
        deice = 2.*reice * 1.e-6
 
        !+---+-----------------------------------------------------------------+
        !..Now we have the final radiative effective size of ice (as function
        !.. of temperature only).  This size represents 3rd moment divided by
        !.. second moment of the ice size distribution, so we can compute a
        !.. number concentration from the mean size and mass mixing ratio.
        !.. The mean (radiative effective) diameter is 3./Slope for an inverse
        !.. exponential size distribution.  So, starting with slope, work
        !.. backwords to get number concentration.
        !+---+-----------------------------------------------------------------+
 
        lambda = 3.0 / deice
        make_icenumber = q_ice * lambda*lambda*lambda / (pi*rho_i)
 
        !+---+-----------------------------------------------------------------+
        !..Example1: Common ice size coming from Thompson scheme is about 30 microns.
        !.. An example ice mixing ratio could be 0.001 g/kg for a temperature of -50C.
        !.. Remember to convert both into MKS units.  This gives N_ice=357652 per kg.
        !..Example2: Lower in atmosphere at T=-10C matching ~162 microns in retab,
        !.. and assuming we have 0.1 g/kg mixing ratio, then N_ice=28122 per kg,
        !.. which is 28 crystals per liter of air if the air density is 1.0.
        !+---+-----------------------------------------------------------------+
 
        return
    end function make_icenumber
 
    !=================================================================================================================
    elemental real function make_dropletnumber (Q_cloud, qnwfa)
 
        !IMPLICIT NONE
 
        real, intent(in):: q_cloud, qnwfa
 
        real, dimension(15), parameter:: g_ratio = (/24,60,120,210,336,   &
        &                504,720,990,1320,1716,2184,2730,3360,4080,4896/)
        double precision:: lambda, qnc
        real:: q_nwfa, x1, xdc
        integer:: nu_c
 
        if (q_cloud == 0) then
            make_dropletnumber = 0
            return
        end if
 
        !+---+
 
        q_nwfa = max(99.e6, min(qnwfa,5.e10))
        nu_c = max(2, min(nint(2.5e10/q_nwfa), 15))
 
        x1 = max(1., min(q_nwfa*1.e-9, 10.)) - 1.
        xdc = (30. - x1*20./9.) * 1.e-6
 
        lambda = (4.0d0 + nu_c) / xdc
        qnc = q_cloud / g_ratio(nu_c) * lambda*lambda*lambda / am_r
        make_dropletnumber = sngl(qnc)
 
        return
    end function make_dropletnumber
 
    !=================================================================================================================
    elemental real function make_rainnumber (Q_rain, temp)
 
        IMPLICIT NONE
 
        real, intent(in):: q_rain, temp
        double precision:: lambda, n0, qnr
 
        if (q_rain == 0) then
            make_rainnumber = 0
            return
        end if
 
        !+---+-----------------------------------------------------------------+
        !.. Not thrilled with it, but set Y-intercept parameter to Marshal-Palmer value
        !.. that basically assumes melting snow becomes typical rain. However, for
        !.. -2C < T < 0C, make linear increase in exponent to attempt to keep
        !.. supercooled collision-coalescence (warm-rain) similar to drizzle rather
        !.. than bigger rain drops.  While this could also exist at T>0C, it is
        !.. more difficult to assume it directly from having mass and not number.
        !+---+-----------------------------------------------------------------+
 
        n0 = 8.e6
 
        if (temp .le. 271.15) then
            n0 = 8.e8
        elseif (temp .gt. 271.15 .and. temp.lt.273.15) then
            n0 = 8. * 10**(279.15-temp)
        endif
 
        lambda = sqrt(sqrt(n0*am_r*6.0/q_rain))
        qnr = q_rain / 6.0 * lambda*lambda*lambda / am_r
        make_rainnumber = sngl(qnr)
 
        return
    end function make_rainnumber
 
end module module_mp_tempo_utils_v2